Re: Allocators and exceptions

["Jeffrey R. Carter" <spam.jrcarter.not@acm.nospam.org>]

Adam Beneschan wrote:
> 
> OK, I think I have one.  GNAT compiles and runs it, although I haven't
> checked the language rules carefully to make sure it's legal.

It looks legal to me. I've added a little test to see what's happening 
with P:

package Pak1 is
    type Rec1 is limited private;
    type Rec1_Acc is access all Rec1;

    function Func1 (R : Rec1_Acc) return Integer;

    procedure Check_P;
private
    type Rec1 is limited record
       F1 : Integer := 123;
       F2 : Integer := Func1 (Rec1'Unchecked_Access);
    end record;
end Pak1;

with Ada.Text_IO;

package body Pak1 is
    P : Rec1_Acc;

    function Func1 (R : Rec1_Acc) return Integer is
    begin
       P := R;
       if R.F1 > 100 then
          raise Constraint_Error;
       end if;
       return 1;
    end Func1;

    procedure Check_P is
       -- null;
    begin -- Check_P
       Ada.Text_IO.Put_Line
          (Item => "P = null => " & Boolean'Image (P = null) );

       if P /= null then
          Ada.Text_IO.Put_Line (Item => Integer'Image (P.F1) );
       end if;
    end Check_P;
end Pak1;

with Pak1;
procedure Test84 is
    -- null;
begin
    Create : declare
       X : Pak1.Rec1_Acc := new Pak1.Rec1;
    begin -- Create
       null;
    end Create;
exception -- Test84
when others =>
    Pak1.Check_P;
end Test84;

and get output:

P = null => FALSE
  123

I suppose P could be dangling, with the memory it points to not yet 
reused, but I suspect that is not the case.

-- 
Jeff Carter
"C++ is like jamming a helicopter inside a Miata
and expecting some sort of improvement."
Drew Olbrich
51