Re: [newbie question] tasks and protected types

[Jacob Sparre Andersen <sparre@hugin.crs4.it>]

Fabio de Francesco wrote:

[...]

>     G : Generator;

Global objects are a _very_ bad idea when doing tasking.  Move it into
your task type.

>     task body Door is
>         Msg : String := "";

Here you make the lenght of the string Msg 0.

>         Val : Positive;
>         Times : Positive;
>     begin
>         accept Start( Str : in String; Tm : in Positive ) do
>             Msg := Str;

And here you try to assign a string of length 6 to a string of length
0.  It will fail with a Constraint_Error, but with tasking you don't
always see the exceptions.

And then I also prefer to keep the printing to a single protected
object.

Here's a modified version of your program using the advice above (and
my pretty-printing style):

-----
with Ada.Text_IO, Ada.Numerics.Float_Random;
use Ada.Numerics.Float_Random;

procedure Manage is

   protected Printer is
      procedure Put_Line (Item : in     String);
   end Printer;

   protected body Printer is
      procedure Put_Line (Item : in     String) is
      begin
         Ada.Text_IO.Put_Line (Item => Item);
         Ada.Text_IO.Flush;
      end Put_Line;
   end Printer;

   protected Tickets is
      procedure Assign (New_Value :    out Positive);
   private
      Data: Integer := 0;
   end Tickets;

   protected body Tickets is
      procedure Assign (New_Value :    out Positive) is
      begin
         Data := Data + 1;
         New_Value := Data;
      end Assign;
   end Tickets;

   subtype Message is String (1 .. 6);

   task type Door is
      entry Start (Str : in     Message;
                   Tm  : in     Positive);
   end Door;

   task body Door is
      G     : Generator;
      Msg   : Message := "      ";
      Val   : Positive;
      Times : Positive;
   begin
      Reset (G);
      accept Start (Str : in     Message;
                    Tm  : in     Positive) do
         Msg := Str;
         Times := Tm;
      end Start;
      for I in 1..Times loop
         delay Duration (Random (G));
         Tickets.Assign (Val);
         Printer.Put_Line (Msg & " counts " & Natural'Image (Val));
      end loop;
   end Door;

   D1 : Door;
   D2 : Door;

begin
   D1.Start ("Task 1", 6);
   D2.Start ("Task 2", 6);
end Manage;
-----

Greetings,

Jacob
-- 
�It will not be forever. - It will just seem like it.� -- Death