Re: Getting the index for an element in mutually referencing containers

[Simon Wright <simon@pushface.org>]

"Dmitry A. Kazakov" <mailbox@dmitry-kazakov.de> writes:

> On 2017-03-12 12:30, Simon Wright wrote:
>> "Dmitry A. Kazakov" <mailbox@dmitry-kazakov.de> writes:
>>
>>> On 2017-03-11 22:46, Simon Wright wrote:
>>
>>>> Basically, I (Simon, now) am having trouble thinking of an
>>>> application where reference counting would be an appropriate
>>>> solution.
>>>
>>> As I said, in practice it is all cases when you would have a
>>> container of mutable elements.
>>
>> I had some trouble understanding your point the first time, and
>> skipped over it (sorry).
>>
>> What's the opposite of "mutable"? constant? because, if so, why
>> wouldn't I use Update_Element?
>
> Yes, But it is almost never element update. Usually what you want is
> to call some mutable operations on the element. The language does not
> offer user-defined by-reference or copy-out-copy-in methods to element
> access.

with Ada.Containers.Vectors;
package Mutable_Elements is
   type Element is record
      Numeral : Integer := 0;
   end record;
   procedure Update (E : in out Element);
   package Element_Vectors is new Ada.Containers.Vectors
     (Index_Type => Positive,
      Element_Type => Element);
   Elements : Element_Vectors.Vector;
end Mutable_Elements;

package body Mutable_Elements is
   procedure Update (E : in out Element) is
   begin
      E.Numeral := E.Numeral + 1;
   end Update;
end Mutable_Elements;

with Ada.Text_IO;
with Mutable_Elements;
procedure Mutable_Elements_Test is
   use Mutable_Elements;
begin
   for J in 1 .. 5 loop
      Elements.Append (Element'(Numeral => J));
   end loop;
   
   Elements (4).Numeral := Elements (4).Numeral + 1;
   Ada.Text_IO.Put_Line ("Elements (4).Numeral: "
                           & Elements (4).Numeral'Img);
                           
   Update (Elements (4));
   Ada.Text_IO.Put_Line ("Elements (4).Numeral: "
                           & Elements (4).Numeral'Img);
end Mutable_Elements_Test;

$ ./mutable_elements_test 
Elements (4).Numeral:  5
Elements (4).Numeral:  6