Re: "C - like: THIS" pointer to a task type inside a task function

[tmoran@acm.org]

> An entry can have in, out, in-out parameters like a subprogram call. You
> can pass parameters in and get the results out, just in one call.

  If the client task, after giving work to the server, needs to do things
other than wait for a result, then adding an "out" parameter won't work.

> It is considered bad design when two components know each other. Usually
> the software is designed in a way that component relationships are
> asymmetric, e.g. the callee knows nothing about the caller. Component knows
> nothing about the container, etc. The advantage of this approach is its
> robustness. You can have as many callers you need without changing the
> callee.

  True, but if the server really does need to call the client, it will
need to know the "name" of the client.  You can do this with
Ada.Task_Identification:

with Ada.Task_Identification;
procedure Testti is

  task type Clients is
    entry Get_Result(Result  : in     Character);
  end Clients;

  task Server is
    entry Get_Work(Work    : in     Character);
  end Server;

  task body Clients is
    Generated_Result: Character;
  begin
    for Jobs in 1 .. 5 loop -- we do want eventual termination of this demo!
      -- generate some work todo, then
      Server.Get_Work(Work => 'w');
      -- do other stuff, then ask for the results
      select
        accept Get_Result(Result  : in     Character) do
          Generated_Result := Result;
        end Get_Result;
        -- use Generated_Result
      or
        terminate; -- Server is dead!  Don't just hang around.  Die.
      end select;
    end loop;
  end Clients;

  Client_List: array (1 .. 10) of Clients;

  task body Server is
    use type Ada.Task_Identification.Task_Id;
    Todo    : Character;
    Result  : Character;
    Source  : Ada.Task_Identification.Task_Id;
  begin
    loop
      select
        accept Get_Work(Work    : in     Character) do
          Todo := Work;
          Source := Get_Work'Caller;
        end Get_Work;
      or
        terminate;
      end select;
      -- handle Todo, generating Result, then pass it back to Source client.
      for I in Client_List'range loop
        if Client_List(I)'Identity = Source then
          Client_List(I).Get_Result(Result);
          exit;
        end if;
        -- if a task other than one in Client_List gave us work, toss it.
      end loop;
    end loop;
  end Server;

begin
  null;  -- Client_List and Server tasks are working away...
end Testti;