Re: Does Ada support endiannes?

[Jeffrey Carter <spam.jrcarter.not@spam.not.acm.org>]

On 12/12/2011 05:44 AM, Gerd wrote:
>
> Any suggestion on how to convert, others that "/" and "mod"?

Let's presume you're on a little-ending machine. Then you can write something like

type Byte is mod 2 ** 8;
for Byte'Size use 8;

type Native is record
    MSB   : Byte;
    MSB_1 : Byte;
    LSB_1 : Byte;
    LSB   : Byte;
end record;

for Native use record
    MSB   at 3 range 0 .. 7;
    MSB_1 at 2 range 0 .. 7;
    LSB_1 at 1 range 0 .. 7;
    LSB   at 0 range 0 .. 7;
end record;
for Native'Size use 32;

function From_Native is new Ada.Unchecked_Conversion
    (Source => Native, Target => Interfaces.Integer_32);
function To_Native is new Ada.Unchecked_Conversion
    (Source => Interfaces.Integer_32, Target => Native);

type Foreign is new Native;

for Foreign use record
    MSB   at 0 range 0 .. 7;
    MSB_1 at 1 range 0 .. 7;
    LSB_1 at 2 range 0 .. 7;
    LSB   at 3 range 0 .. 7;
end record;
for Foreign'Size use 32;

function From_Foreign is new Ada.Unchecked_Conversion
    (Source => Foreign, Target => Interfaces.Integer_32);
function To_Foreign is new Ada.Unchecked_Conversion
    (Source => Interfaces.Integer_32, Target => Foreign);

Now, if you have something in big-endian format in Value, you can convert it to 
little-ending by

From_Native (Native (To_Foreign (Value) ) )

which you would probably want to encapsulate

function Foreign_To_Native (Value : in Interfaces.Integer_32)
return Interfaces.Integer_32 is
    -- null;
begin -- Foreign_To_Native
    return From_Native (Native (To_Foreign (Value) ) );
end Foreign_To_Native;

You could also read your foreign value byte by byte, putting the bytes into the 
appropriate fields of a Native, then unchecked-convert that to an integer.

-- 
Jeff Carter
"Pray that there's intelligent life somewhere up in
space, 'cause there's bugger all down here on earth."
Monty Python's Meaning of Life
61

--- Posted via news://freenews.netfront.net/ - Complaints to news@netfront.net ---