Re: Adding offset to 'Address

[tmoran@acm.org]

>  Raw_Bytes : access Unsigned_Char
>  for Ethernet_Header'Address use Raw_Bytes.all'Address;
>
>and additionally need something like:
>  for IP_Packet'Address use Raw_Bytes.all'Address + Ethernet_Header'Size;

It's not clear to me exactly what problem you are trying to get past.
How about something like:

with Ada.Unchecked_Conversion,
     Interfaces.C;
procedure Eiptest is
  type Ethernet_Header_Type is new Integer;          -- or whatever
  type IP_Packet_Type is array (1 .. 5) of Integer;  -- "

  type R_Type is record
    Ethernet_Header: Ethernet_Header_Type;
    IP_Packet: IP_Packet_Type;
    Other_Stuff : Integer;
  end record;
  for R_Type use record
    Ethernet_Header at 0 range 0 .. 31;
    IP_Packet at 4 range 0 .. 159;
    Other_Stuff at 30 range 0 .. 31;
  end record;

  type Lpvoid is access all Interfaces.C.Char;
  type R_Ptr_Type is access all R_Type;

  function Convert is new Ada.Unchecked_Conversion
    (Source => Lpvoid, Target => R_Ptr_Type);

  procedure Process(Raw_Bytes: in Lpvoid) is
    R_Ptr   : constant R_Ptr_Type := Convert(Raw_Bytes);
    This_IP_Packet: IP_Packet_Type renames R_Ptr.IP_Packet;
  begin
    null; -- do something with This_IP_Packet
  end Process;

  Buffer : Interfaces.C.Char_Array(1 .. 100);

begin
  Process(Buffer(1)'access);
end Eiptest;