Re: C array to Ada pointer to unconstrained array without copying memory

[Jeffrey Carter <spam@spam.com>]

Duncan Sands wrote:

> [have Length and Ptr]
> 
> subtype Array2 is Ada_Array (1 .. Length);
> 
> X : Array2;
> for X'Address use Ptr; -- ok, Ptr should be of type System'Address, but hey!

You should also have

pragma Import (Ada, X);

to avoid initializing X. But this may not provide usable bounds for X. 
If, for example, your compiler stores the bounds in memory just before 
the 1st element of X, this may result in garbage for the bounds of X.

The general technique is to use Ptr as an access value to something as 
large or larger than Length can ever be, then immediately take a slice 
and pass it elsewhere. Slicing generates the bounds information. The 
following compiles:

procedure Bound_Generation is
    type T is new Integer;

    type Real is array (Positive range <>) of T;
    subtype Huge is Real (Positive);

    type Huge_Ptr is access all Huge;
    pragma Convention (C, Huge_Ptr);

    X_Ptr  : Huge_Ptr;
    Length : Positive;

    procedure Deal_With_X (X : in Real) is
    begin -- Deal_With_X
       null;
    end Deal_With_X;
begin -- Bound_Generation
    -- Get X_Ptr and Length from C
    Deal_With_X (X => X_Ptr (1 .. Length) );
end Bound_Generation;

> And then you can make use of X.  However being defined on the stack, it
> can be quite awkward to use.  It would be nice to have the same thing but
> with X dynamically allocated.  For example,

There is generally no need for a pointer to X; I'd have to know more 
about what you're trying to do to understand why you say you want one. 
With GNAT, you could use 'Unrestricted_Access on X within Deal_With_X to 
obtain such a pointer. Or, instead of calling a subprogram, you could do 
something like:

declare
    type Real_Ptr is access all Real;

    X : Real_Ptr;

    Result : aliased Real := X_Ptr (1 .. Length);
begin
    X := Result'Access;
    -- Deal with X here
end;

-- 
Jeff Carter
"Your mother was a hamster and your father smelt of elderberries."
Monty Python & the Holy Grail
06