Re: HELP | function Is_Open (File : File_Type) return Boolean; package ada.text_io

[Niklas Holsti <niklas.holsti@tidorum.invalid>]

On 15-10-26 12:21 , comicfanzine@gmail.com wrote:
> Can someone please post a simple code in which this function is used , i'm lost , thanks .

The following program can be run with or without command-line arguments. 
If, and only if, there are command-line arguments, the program creates 
and writes some text to a file called my_log_file.txt.


with Ada.Command_Line;
with Ada.Text_IO;

procedure Ex_Is_Open
is

    Log_File : Ada.Text_IO.File_Type;
    --
    -- File for log output.
    -- Created only if the program has command-line arguments.


    procedure Log (Text : in String)
    --
    -- Log the Text, if the Log_File is open.
    --
    is
    begin

       if Ada.Text_IO.Is_Open (Log_File) then

          Ada.Text_IO.Put_Line (Log_File, Text);

       end if;

    end Log;


begin  -- Ex_Is_Open

    Log ("This will not appear in the log.");

    if Ada.Command_Line.Argument_Count > 0 then

       Ada.Text_IO.Put_Line ("Creating log file my_log_file.txt.");

       Ada.Text_IO.Create (
          File => Log_File,
          Name => "my_log_file.txt",
          Mode => Ada.Text_IO.Out_File);

    end if;

    Log ("This will appear iff there are command-line arguments.");

    if Ada.Text_IO.Is_Open (Log_File) then
       -- We close the log.
       -- Trying to Close the Log_File if it is not open
       -- raises the exception Ada.Text_IO.Status_Error.

       Ada.Text_IO.Close (Log_File);

    end if;

    Log ("This will not appear in the log.");

end Ex_Is_Open;



-- 
Niklas Holsti
Tidorum Ltd
niklas holsti tidorum fi
       .      @       .