From mboxrd@z Thu Jan  1 00:00:00 1970
X-Spam-Checker-Version: SpamAssassin 3.4.4 (2020-01-24) on polar.synack.me
X-Spam-Level: 
X-Spam-Status: No, score=-1.9 required=5.0 tests=BAYES_00 autolearn=ham
	autolearn_force=no version=3.4.4
X-Google-Language: ENGLISH,ASCII-7-bit
X-Google-Thread: 103376,a8eff9f0aa872e3f
X-Google-Attributes: gid103376,public
X-Google-ArrivalTime: 2003-09-07 22:55:48 PST
Path: 
 archiver1.google.com!news1.google.com!newsfeed.stanford.edu!news-spur1.maxwell.syr.edu!news.maxwell.syr.edu!news.kiev.sovam.com!Svitonline.COM!not-for-mail
From: max1@mbank.com.ua
Newsgroups: comp.lang.ada
Subject: Re: GtkAda and the Tree_Store Widget
Date: Mon, 08 Sep 2003 08:56:55 +0300
Organization: Svit Online (post does not reflect views of Golden Telecom)
Message-ID: <bjh5l2$1g61$1@news.kiev.sovam.com>
References: <soW5b.44493$cj1.9627@fed1read06>
NNTP-Posting-Host: 62.64.80.155
Mime-Version: 1.0
Content-Type: text/plain; charset=us-ascii; format=flowed
Content-Transfer-Encoding: 7bit
X-Trace: news.kiev.sovam.com 1063000547 49345 62.64.80.155 (8 Sep 2003
 05:55:47 GMT)
X-Complaints-To: abuse@svitonline.com
NNTP-Posting-Date: Mon, 8 Sep 2003 05:55:47 +0000 (UTC)
User-Agent: Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.4) Gecko/20030901
X-Accept-Language: en, ru, uk
In-Reply-To: <soW5b.44493$cj1.9627@fed1read06>
X-Enigmail-Version: 0.76.4.0
X-Enigmail-Supports: pgp-inline, pgp-mime
Xref: archiver1.google.com comp.lang.ada:42262
Date: 2003-09-08T08:56:55+03:00
List-Id: <comp.lang.ada>

Adam Puleo wrote:
> I'm trying to use the Tree_Store widget in GtkAda 2.2.0 but nothing shows up

Try this:

with Glib;
with Gtk.Box;
with Gtk.Main;
with Gtk.Enums;
with Gtk.Widget;
with Gtk.Window;
with Gtk.Button;
with Gtk.Tree_View;
with Gtk.Tree_Store;
with Gtk.Tree_Model;
with Gtk.Tree_View_Column;
with Gtk.Scrolled_Window;
with Gtk.Cell_Renderer_Text;

procedure Gtk_Test is

    use type Glib.Gint;

    Box    : Gtk.Box.Gtk_Box;
    Window : Gtk.Window.Gtk_Window;
    Scroll : Gtk.Scrolled_Window.Gtk_Scrolled_Window;
    Button : Gtk.Button.Gtk_Button;
    Store  : Gtk.Tree_Store.Gtk_Tree_Store;
    View   : Gtk.Tree_View.Gtk_Tree_View;
    Parent : Gtk.Tree_Model.Gtk_Tree_Iter := Gtk.Tree_Model.Null_Iter;
    Iter   : Gtk.Tree_Model.Gtk_Tree_Iter;
    Types  : Glib.GType_Array (0 .. 0);
    Column : Gtk.Tree_View_Column.Gtk_Tree_View_Column;
    Render : Gtk.Cell_Renderer_Text.Gtk_Cell_Renderer_Text;
    Ignore : Glib.Gint;
begin
    Gtk.Main.Init;
    Gtk.Window.Gtk_New (Window);
    Gtk.Box.Gtk_New_Vbox (Box);
    Gtk.Button.Gtk_New (Button, "Hello World");
    Gtk.Box.Pack_Start (Box, Button, False, False);

    Gtk.Scrolled_Window.Gtk_New (Scroll);
    Gtk.Scrolled_Window.Set_Border_Width (Scroll, 5);
    Gtk.Scrolled_Window.Set_Policy
      (Scroll,
       Gtk.Enums.Policy_Automatic,
       Gtk.Enums.Policy_Automatic);
    Gtk.Box.Pack_Start (Box, Scroll);

    Types (0) := Glib.GType_String;
    Gtk.Tree_Store.Gtk_New (Store, Types);
    for I in 1 .. 1000 loop
       Iter := Gtk.Tree_Model.Null_Iter;
       Gtk.Tree_Store.Append (Store, Iter, Parent);
       Gtk.Tree_Store.Set (Store, Iter, 0,
          Gtk.Tree_Model.To_String (Gtk.Tree_Store.Get_Path (
            Store, Iter)));
    end loop;

    Gtk.Tree_View.Gtk_New (View, Store);
    Gtk.Cell_Renderer_Text.Gtk_New (Render);

    for I in 1 .. Glib.Gint'(18) loop
       Gtk.Tree_View_Column.Gtk_New (Column);
       Gtk.Tree_View_Column.Pack_Start (Column, Render, True);
       Gtk.Tree_View_Column.Add_Attribute (Column, Render, "text", 0);
       Ignore := Gtk.Tree_View.Append_Column (View, Column);
    end loop;

    Gtk.Scrolled_Window.Add (Scroll, View);

    Gtk.Window.Add (Window, Box);

    Gtk.Scrolled_Window.Show (Scroll);
    Gtk.Button.Show (Button);
    Gtk.Tree_View.Show (View);
    Gtk.Box.Show (Box);
    Gtk.Window.Show (Window);
    Gtk.Main.Main;
end Gtk_Test;