Re: A simple ADA puzzle (I haven't the answer)

["Frank J. Lhota" <NOSPAM.lhota.adarose@verizon.net>]

The problem with your definition of String_Type is that an unconstrained
object of this type would require an outrageous amount of memory. Assume
that we declare:

    My_Name : STRING_TYPE;

Since My_Name is unconstrained, we can assign any STRING_TYPE value to
My_Name, including

    My_Name := STRING_TYPE'( Len => Integer'Last, String => ( others => '
' ) );

So even though My_Name.Len is initially 0, My_Name must be allocated enough
space to contain the largest object of STRING_TYPE. Frankly, I'd be
surprised if there was space for one such object. There is nothing
surprising about getting some sort of error when declaring an array of 3
unconstrained objects of type STRING_TYPE, although Storage_Error should
have been raised instead of Constraint_Error.

The right way to fix this depends on one question: is there a reasonable
upper bound to the length of the Len discriminant?

----------------------------------------

If  there is a reasonable upper limit on the LEN discriminant, say 100, we
can constrain the LEN component as follows:

  type LEN_TYPE is array (INTEGER range <>)
    of CHARACTER;


  subtype STRING_LEN is INTEGER range 0 .. 100;

  type STRING_TYPE (LEN : STRING_LEN := 0) is
    record
      STRING : LEN_TYPE (1 .. LEN);
    end record;

With these declararations, LEN is constrained to be no larger than 100. You
can now declare an unconstrained object of type STRING_TYPE without
requiring ridiculous amounts of space.

----------------------------------------

If  there is no reasonable upper limit on the LEN discriminant, if say LEN
can vary from 1 to hundreds of thousands, then the best solution would be to
use an array of pointers. This would be the only reasonable way to create an
array of objects of widely varying sizes. For example:

  type LEN_TYPE is array (INTEGER range <>)
    of CHARACTER;

  type STRING_TYPE (LEN : INTEGER := 0) is
    record
      STRING : LEN_TYPE (1 .. LEN);
    end record;

  type STRING_ACC is access all STRING_TYPE;
  procedure Deallocate is
     new Ada.Unchecked_Deallocation( STRING_TYPE, STRING_ACC );

  type UNC2_ARRAY_TYPE is array (INTEGER range <>)
    of STRING_ACC;

This solution does require that the array component values be allocated (and
deallocated once you are finished with them), but it does allow you to make
a table of STRING_TYPE values that take on the full range of LEN
discriminants.