From mboxrd@z Thu Jan  1 00:00:00 1970
X-Spam-Checker-Version: SpamAssassin 3.4.4 (2020-01-24) on polar.synack.me
X-Spam-Level: 
X-Spam-Status: No, score=-0.3 required=5.0 tests=BAYES_00,
	REPLYTO_WITHOUT_TO_CC autolearn=no autolearn_force=no version=3.4.4
Path: 
 eternal-september.org!reader01.eternal-september.org!reader02.eternal-september.org!news.eternal-september.org!news.eternal-september.org!news.eternal-september.org!feeder.eternal-september.org!aioe.org!.POSTED!not-for-mail
From: "Dmitry A. Kazakov" <mailbox@dmitry-kazakov.de>
Newsgroups: comp.lang.ada
Subject: Re: Quick question regarding limited type return syntax
Date: Sat, 2 Aug 2014 18:56:46 +0200
Organization: cbb software GmbH
Message-ID: <a5pzvn575hsz.8rt38rwse8bg.dlg@40tude.net>
References: <166aaec5-5e9c-40e0-9b07-9b9c7d5f7f33@googlegroups.com>
 <EngCv.101926$Ji3.44609@fx16.iad>
 <16a6846f-2964-438a-ab9b-2029075f7924@googlegroups.com>
 <bf9193d6-e1a8-4df3-8e36-b07a2b07655e@googlegroups.com>
 <lret2q$fs$1@loke.gir.dk> <lrfh8k$rpi$1@dont-email.me>
 <lrgpg1$40g$1@loke.gir.dk> <D7TCv.160339$HF6.16263@fx30.iad>
 <c43h9sFgdq8U1@mid.individual.net>
 <20m59uxjlygw$.2mpabkt469vp.dlg@40tude.net>
 <wcciombyqmq.fsf@shell01.TheWorld.com>
 <cp8rrf40gpmj.zx1py68uwkjl$.dlg@40tude.net>
 <wccegwzyn76.fsf@shell01.TheWorld.com>
Reply-To: mailbox@dmitry-kazakov.de
NNTP-Posting-Host: qHNcUCBwwd01dPSBp/L1cg.user.speranza.aioe.org
Mime-Version: 1.0
Content-Type: text/plain; charset="us-ascii"
Content-Transfer-Encoding: 7bit
X-Complaints-To: abuse@aioe.org
User-Agent: 40tude_Dialog/2.0.15.1
X-Notice: Filtered by postfilter v. 0.8.2
Xref: news.eternal-september.org comp.lang.ada:21406
Date: 2014-08-02T18:56:46+02:00
List-Id: <comp.lang.ada>

On Sat, 02 Aug 2014 10:34:53 -0400, Robert A Duff wrote:

> "Dmitry A. Kazakov" <mailbox@dmitry-kazakov.de> writes:
> 
>> On Sat, 02 Aug 2014 09:20:45 -0400, Robert A Duff wrote:
>>
>>> "Dmitry A. Kazakov" <mailbox@dmitry-kazakov.de> writes:
>>> 
>>>>...Dispatching calls
>>>> through class-wide access discriminants upon initialization/finalization.
>>> 
>>> Can you please give an example of what you mean?
>>
>> Components not discriminants. I had Rosen's trick in mind:
>>
>>    type T is ...
>>        Self : not null access T := T'Unchecked_Access;
> 
> Sorry, I still don't get it.  I don't see any class-wide types or
> dispatching calls there.  Also, it's illegal as written (the Rosen trick
> is only allowed for limited types.)  Perhaps a complete compilable
> example would help illustrate the language anomaly you are talking
> about.

with Ada.Finalization;
with Ada.Text_IO;
procedure Test is
   package P is
      type T is new Ada.Finalization.Limited_Controlled with record
         Self : not null access T'Class := T'Unchecked_Access;
      end record;
      overriding procedure Initialize (X : in out T);
      procedure Foo (X : in out T) is null;
   end P;
   
   package body P is
      procedure Initialize (X : in out T) is
      begin
         X.Self.Foo;
      end Initialize;   
   end P;
   
   package Q is
      use P;
      type S is new T with record
         I : Integer;
      end record;
      overriding procedure Initialize (X : in out S);
      overriding procedure Foo (X : in out S);
   end Q;
   
   package body Q is
      procedure Initialize (X : in out S) is
      begin
         T (X).Initialize;
         X.I := 1;
      end Initialize;
      procedure Foo (X : in out S) is
      begin
         X.I := X.I + 1;
      end Foo;
   end Q;
   
   Y : Q.S;
begin
   Ada.Text_IO.Put_Line (Integer'Image (Y.I));
end Test;

-- 
Regards,
Dmitry A. Kazakov
http://www.dmitry-kazakov.de