Re: Benchmarking

[Gautier write-only <gautier_niouzes@hotmail.com>]

Hello!
Here is the generic Timing procedure I'm using for "shooting-out" a
bit. The instanciation for one test holds then in one line:
  with Timing, Fasta_O, Fasta; procedure Fasta_Timing is new Timing
( 100, "Fasta 2005", "Fasta 2009", Fasta_O, Fasta);
HTH
Gautier

-- Timing of two algorithms P1, P2 (wall clock time).
-- P1 and P2 are run "runs" times (+1 as "tour de chauffe").

generic
  runs: Positive;
  n1, n2: String;
  with procedure P1;
  with procedure P2;
procedure Timing;

with Ada.Text_IO;                       use Ada.Text_IO;
with Ada.Calendar;                      use Ada.Calendar;
with Ada.Numerics.Float_Random;         use Ada.Numerics.Float_Random;

procedure Timing is
  a1,z1,a2,z2: Time;
  f, t1s,t2s: Long_Float;
  package LFIO is new Ada.Text_IO.Float_IO(Long_Float); use LFIO;
  gen: Generator;
begin
  Put_Line("Heating..."); -- Skip (most of) cache effects
  P1;
  P2;
  -- Now we start for real:
  t1s:= 0.0;
  t2s:= 0.0;
  Reset(gen);
  for run in 1..runs loop
    Put_Line(Standard_Error, "========= Run" & run'img & " of" &
runs'img);
    if Random(gen) > 0.5 then
      a1:= Clock;  P1;  z1:= Clock;
      a2:= Clock;  P2;  z2:= Clock;
    else
      a2:= Clock;  P2;  z2:= Clock;
      a1:= Clock;  P1;  z1:= Clock;
    end if;
    Put_Line(Standard_Error, "Time in seconds for...");
    Put(Standard_Error, "P1 ("&n1&"): " & Duration'Image(z1-a1));
    Put(Standard_Error, " -- average so far: ");
    Put(Standard_Error, t1s / Long_Float(run),0,5,0);
    New_Line(Standard_Error);
    Put(Standard_Error, "P2 ("&n2&"): " & Duration'Image(z2-a2));
    Put(Standard_Error, " -- average so far: ");
    Put(Standard_Error, t2s / Long_Float(run),0,5,0);
    New_Line(Standard_Error);
    f:= Long_Float(z2-a2) / Long_Float(z1-a1);
    Put(Standard_Error, "\--> time factor (T2/T1): "); Put
(Standard_Error, f,0,5,0);
    t1s:= t1s + Long_Float(z1-a1);
    t2s:= t2s + Long_Float(z2-a2);
    Put(Standard_Error, " -- average so far: ");
    Put(Standard_Error, t2s / t1s,0,5,0);
    New_Line(Standard_Error);
  end loop;
  -- Put("[press return]"); Skip_Line;
end;