Re: How to exit a loop with keyboard input

[John McCormick <mccormick@cs.uni.edu>]

On Apr 12, 5:36 am, Jerry <lancebo...@qwest.net> wrote:
> Thanks, Georg and Manuel, for testing. I'm on OS X 10.5.8 and:
>
> MBPro:/ me$ gnat
> GNAT 4.4.0 20080314 (experimental) [trunk revision 133226]
> Copyright 1996-2007, Free Software Foundation, Inc.
>
> I've tried the program on three different terminal programs with the
> same result: it prints out 0 and waits for RETURN, then prints out 1,
> etc. If I hit q then RETURN the loop is exited. But the loop never
> "free-runs."
>
> Jerry

Perhaps the Asynchronous Transfer of Control mechanism would be
appropriate.  Here is some GNAT code that runs under Windows XP in
which the input loop is interrutpted by Ctrl-c.  The interrupt handler
must be at the library level so I put it in its own package.

   select
      Ctrl_C_Interrupt.Wait;
      Put_Line ("Handled Ctrl C");
   then abort
      loop
         Put_Line ("Enter an integer (Ctrl C to exit)");
         Get (Value);
         Put (Value);
         New_Line;
      end loop;
   end select;

-----------------------------------------------------------
with Ada.Interrupts.Names;
package Ctrl_C is

   protected Ctrl_C_Interrupt is
      entry Wait;
      procedure Handler;
      pragma Attach_Handler (Handler, Ada.Interrupts.Names.SIGINT);
      pragma Interrupt_Priority;
   private
      Received : Boolean := False;
   end Ctrl_C_Interrupt;
end Ctrl_C;

-----------------------------------------------------------
package body Ctrl_C is

   protected body Ctrl_C_Interrupt is
      procedure Handler is
      begin
         Received := True;
      end Handler;

      entry Wait when Received is
      begin
         Received := False;
      end Wait;
   end Ctrl_C_Interrupt;

end Ctrl_C;

John