Re: Algorithms Homework Help?!?!

[Shark8 <onewingedshark@gmail.com>]

Um, there's nothing there suggestive of a binary-search, or ANY search.
But here's an example of how to do the groupings.

Pragma Ada_2012;

With
Ada.Text_IO,
Ada.Text_IO.Text_Streams;

Procedure Test is

    Type Color is ( Red, Blue, Green, Yellow, Brown );

    Type MM_Array is Array(Color Range <>) of Natural;
    
    --------------------------
    -- Forward Declarations --
    --------------------------
    
    Function Maximum( Candy : MM_Array ) Return Natural
      with Pre => Candy'Length in Positive;
    
    Function Group( Group_Size : Positive; Candy : MM_Array ) Return Natural
      with Pre => Candy'Length in Positive AND Maximum(Candy) >= Group_Size;
    

    -----------------------
    --  Function Bodies  --
    -----------------------
    
    Function Maximum( Candy : MM_Array ) Return Natural is
    begin
	Return Result : Natural := Natural'First do
	    For Value of Candy loop
		Result:= Natural'Max( Result, Value );
	    End loop;
	End return;
    end Maximum;
    
    Function Group( Group_Size : Positive; Candy : MM_Array ) Return Natural is
    begin
	Return Result : Natural := 0 do
	    For Value of Candy loop
		Result:= Result + Value / Group_Size;
	    End loop;
	End return;
    end Group;
    
    Candies : MM_Array := (Red => 11, Blue => 9, Green => 5);
Begin
    Ada.Text_IO.New_Line;
    Ada.Text_IO.Put_Line( "Max:  " & Maximum(Candies)'Img  );
    Ada.Text_IO.Put_Line( "Group:" & Group(8, Candies)'Img  );
End Test;