Re: Using a string as a binary operator

[Gene <gene.ressler@gmail.com>]

On Oct 14, 11:35 am, Joe <joesmo...@gmail.com> wrote:
> Hey all,
>
> I'm trying to build a simple stack the evaluates expressions in
> postfix notation (i.e. "1 2 +").  I can't find a way to use the
> operator directly when I get to it.  When I get to the  "+", but how
> do I apply this string to 1 and 2?  The best I can do is make a case
> statement that has a case for each binary operator, but this seems
> very klunky.  I know you can write "+"(1,2) to return 3 but how do I
> get Ada to recognize the string as an operator?  Here's a short
> example of what I would like to do:
>
> with Ada.Integer_Text_IO;  use Ada.Integer_Text_IO;
> procedure Operators is
>    Plus : String := "+";
> begin
>    Put( Plus(1,2));
> end Operators;
>

The "+" in Ada code such as "+"(1, 2) is a function call, just like
f(1, 2).  You can't cast a string "+" to a function in Ada, just as
you can't cast "f".  You have to convert the string yourself.  Here is
a toy code with many things go fix:

with Ada.Text_IO; use Ada.Text_IO;

procedure Postfix is

   subtype Number is Integer;

   Operands : array(1 .. 1000) of Number;
   SP : Natural := 0;

   procedure Push(X : in Number) is
   begin
      SP := SP + 1;
      Operands(SP) := X;
   end Push;

   procedure Pop(X : out Number) is
   begin
      X := Operands(SP);
      SP := SP - 1;
   end Pop;

   Buf : String(1 .. 1000);
   Last : Natural;
   X, Y : Number;
begin
   loop
      Get_Line(Buf, Last);
      exit when Last = 0;
      case Buf(1) is
         when '+' =>
            Pop(X); Pop(Y); Push(X + Y);
         when '-' =>
            Pop(X); Pop(Y); Push(X - Y);
         when '*' =>
            Pop(X); Pop(Y); Push(X * Y);
         when '/' =>
            Pop(X); Pop(Y); Push(X / Y);
         when others =>
            Push(Number'Value(Buf(1 .. Last)));
      end case;
      if SP = 1 then
         Put_Line(Number'Image(Operands(1)));
      end if;
   end loop;
end Postfix;