From mboxrd@z Thu Jan  1 00:00:00 1970
X-Spam-Checker-Version: SpamAssassin 3.4.4 (2020-01-24) on polar.synack.me
X-Spam-Level: 
X-Spam-Status: No, score=-1.9 required=5.0 tests=BAYES_00 autolearn=ham
	autolearn_force=no version=3.4.4
X-Google-Thread: 109d8a,ef399b8656ef0ac9
X-Google-NewGroupId: yes
X-Google-Thread: 1014db,ef399b8656ef0ac9
X-Google-NewGroupId: yes
X-Google-Thread: 1094ba,ef399b8656ef0ac9
X-Google-NewGroupId: yes
X-Google-Thread: 101deb,51918afc602d6523
X-Google-NewGroupId: yes
X-Google-Thread: 103376,51918afc602d6523
X-Google-NewGroupId: yes
X-Google-Thread: 107079,51918afc602d6523
X-Google-NewGroupId: yes
X-Google-Attributes: 
 gid9ef9b79ae9,gid4516fb5702,gid8d3408f8c3,gidbda4de328f,gida07f3367d7,gid7a498f3897,domainid0,public,usenet
X-Google-Language: ENGLISH,ASCII-7-bit
Path: 
 g2news1.google.com!news3.google.com!feeder.news-service.com!news.netcologne.de!newsfeed-fusi2.netcologne.de!newsfeed.straub-nv.de!goblin3!goblin.stu.neva.ru!exi-transit.telstra.net!news.telstra.net!exi-spool.telstra.net!exi-reader.telstra.net!not-for-mail
From: "robin" <robin51@dodo.com.au>
Newsgroups: 
 sci.math,comp.lang.c,comp.lang.fortran,comp.lang.pl1,comp.lang.ada,sci.math.num-analysis
References: <08db9776-d933-44a5-a20f-7a137e81cce5@5g2000yqz.googlegroups.com>
Subject: Re: Ensuring the long period of the  KISS4691 RNG.
Date: Mon, 23 Aug 2010 18:01:34 +1000
X-Priority: 3
X-MSMail-Priority: Normal
X-Newsreader: Microsoft Outlook Express 6.00.2900.5931
X-MimeOLE: Produced By Microsoft MimeOLE V6.00.2900.5931
Message-ID: <4c722ae5$0$1261$c30e37c6@exi-reader.telstra.net>
NNTP-Posting-Host: 123.3.25.208
X-Trace: 1282550501 exi-reader.telstra.net 1261 123.3.25.208:1046
Xref: g2news1.google.com sci.math:178862 comp.lang.c:101332
 comp.lang.fortran:27032 comp.lang.pl1:1649 comp.lang.ada:13655
 sci.math.num-analysis:14359
Date: 2010-08-23T18:01:34+10:00
List-Id: <comp.lang.ada>

"geo" <gmarsaglia@gmail.com> wrote in message news:08db9776-d933-44a5-a20f-7a137e81cce5@5g2000yqz.googlegroups.com...

| Below is a revised listing of the C version;
| changes should be transparent for versions
| kindly provided by interested viewers---in Fortran,
| PL/1 and others.

Below is my PL/I version, using signed arithmetic,
which I confirm delivers the same test results as previously,
and which are the same results as the signed version.

(NOSIZE, NOFOFL):
RNG: PROCEDURE OPTIONS (MAIN, REORDER);

   declare (xs initial (521288629), xcng initial (362436069),
            Q(0:4690) ) static fixed binary (31);

MWC: procedure () returns (fixed binary (31));
   declare (t,x,i) fixed binary (31);
   declare (c initial (0), j initial (4691) ) fixed binary (31) static;
   declare t1 fixed binary (31);

   if j < hbound(Q,1) then j = j + 1; else j = 0;
   x = Q(j); if x = 0 then do; Q(j) = c; c = 0; return(Q(j)); end;
   t = isll(x,13)+c+x;
   /* Tests x >= t by computing x - t in two parts. */
   t1 = isrl(x, 2) - isrl(t, 2);
   if t1  = 0 then t1 = iand(x, 3) - iand(t, 3);
   if t1 >= 0 then t1 = 1; else t1 = 0;
   c = t1 + isrl(x, 19);
   Q(j)=t;
   return (t);
end MWC;

CNG: procedure returns (fixed binary (31));
  xcng=bin(69069)*xcng+bin(123);
  return (xcng);
end CNG;

XXS: procedure returns (fixed binary (31));
   xs = ieor (xs, isll(xs, 13) );
   xs = ieor (xs, isrl(xs, 17) );
   xs = ieor (xs, isll(xs,  5) );
   return (xs);
end XXS;

KISS: procedure returns (fixed binary (31));
   return ( MWC()+CNG+XXS );
end KISS;

   declare (i,x) fixed binary (31);
   declare y fixed decimal (11);

   Q = CNG+XXS; /* Initialize. */
   do i = 1 to 1000000000; x=MWC(); end;
   put skip edit (" Expected MWC result = 3740121002", 'computed =', x)
      (a, skip, x(12), a, f(11));
   y = iand(x, 2147483647);
   if x < 0 then y = y + 2147483648;
   put skip edit (y) (x(11), f(22)); put skip;
   do i = 1 to 1000000000; x=KISS; end;
   put skip edit ("Expected KISS result = 2224631993", 'computed =', x)
      (a, skip, x(12), a, f(11));
   y = iand(x, 2147483647);
   if x < 0 then y = y + 2147483648;
   put skip edit (y) (x(11), f(22));

end RNG;