Re: Interfacing Ada with C

["Dmitry A. Kazakov" <mailbox@dmitry-kazakov.de>]

On Sun, 25 Jul 2010 05:21:44 -0700 (PDT), Ada novice wrote:

> What would the best way to interface this with Ada? The elements of my
> matrix will be formed in Ada, then the matrix will be passed to C to
> calculate the eigenvalues and then the latter passed back to Ada. The
> size of my matrix will be fixed say 3 x 3. As a novice in Ada, I would
> like to learn good programming practice and the best way is to use
> codes and learn from experts here in Ada.

Something like (not tested):

with Interfaces.C;  use Interfaces.C;
package IMSL is
   type Float_Matrix is -- Row-wise, packed/aligned
      array (Positive range <>, Positive range <>) of C_Float;
   pragma Convention (C, Float_Matrix);
   type F_Complex is record
      Re : C_Float;
      Im : C_Float;
   end record;
   pragma Convention (C, F_Complex);
   type Complex_Array is array (Positive range <>) of F_Complex;
   pragma Convention (C, Complex_Array);

   function F_Eig_Gen (Matrix : Float_Matrix) return Complex_Array;
 end IMSL;

package body IMSL is
   procedure Free (Ptr : System.Address);
   pragma Import (C, Free, "free");
      
   function F_Eig_Gen (Matrix : Float_Matrix) return Complex_Array is
   begin
      if Matrix'Length (1) /= Matrix'Length (2) then
         raise Constraint_Error;
      end if;
      declare -- No idea, how they report convergence/accuracy errors
         function Internal (N : Int; A : Address; Terminator : Address :=
            Null_Address) return Address;
         pragma Import (C, Internal, "imsl_f_eig_gen");
         Ptr  : Address := Internal
                           (  Matrix'Length (1),
                              Matrix (  Matrix'First (1),
                                        Matrix'First (2)
                                     )' Address
                           );
         Data : Complex_Array (1..Matrix'Length (1));
         for Data'Address use Ptr;
         pragma Import (Ada, Data);
         Result : Complex_Array := Data; -- Copy, we don't own that memory
      begin
         Free (Ptr);
         return Result;
      end;
   end F_Eig_Gen;
end IMSL;

Used as:

   Values : Complex_Array :=
      F_Eig_Gen
      (  (  ( 8.0,-1.0,-5.0),
            (-4.0, 4.0,-2.0),
            (18.0,-5.0,-7.0)  )
      );

-- 
Regards,
Dmitry A. Kazakov
http://www.dmitry-kazakov.de